home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / dissolve.pro < prev    next >
Text File  |  1997-07-08  |  3KB  |  121 lines
  1. ; $Id: dissolve.pro,v 1.3 1997/01/15 03:11:50 ali Exp $
  2. ;
  3. ; Copyright (c) 1990-1997, Research Systems, Inc.  All rights reserved.
  4. ;    Unauthorized reproduction prohibited.
  5. ;
  6.  
  7. pro DISSOLVE, image, SIZ = siz, X0 = x0, Y0 = y0, DELAY = delay, $
  8.     ORDER = order
  9. ;+
  10. ; NAME:
  11. ;    DISSOLVE
  12. ;
  13. ; PURPOSE:
  14. ;    A digital "dissolve" effect for images.  Copies the pixels (arranged
  15. ;    into square tiles) from the image to the display in pseudo-random
  16. ;    order.
  17. ;
  18. ; CATEGORY:
  19. ;    Image display.
  20. ;
  21. ; CALLING SEQUENCE:
  22. ;    DISSOLVE, Image
  23. ;
  24. ; INPUTS:
  25. ;    Image:    The image to be displayed.  It is assumed that the image is
  26. ;        already scaled.  Byte-valued images display most rapidly.
  27. ;
  28. ; OPTIONAL INPUT PARAMETERS:
  29. ;    None.
  30. ;
  31. ; KEYWORD PARAMETERS:
  32. ;    SIZ:    Size of square tile.  The default is 32 x 32 pixels.
  33. ;
  34. ;    X0, Y0: The X and Y offsets of the lower-left corner of the image on 
  35. ;        screen.  The defaults are X0 = 0 and Y0 = 0.
  36. ;
  37. ;    DELAY:    The wait between displaying tiles.  The default is 0.01 secs.
  38. ;
  39. ;    ORDER:    The Image display order:      0 = default = bottom up.
  40. ;                        1 = top-down.
  41. ;
  42. ; OUTPUTS:
  43. ;    No explicit outputs.
  44. ;
  45. ; COMMON BLOCKS:
  46. ;    None.
  47. ;
  48. ; SIDE EFFECTS:
  49. ;    The image is written to the screen.
  50. ;
  51. ; RESTRICTIONS:
  52. ;    None, but the effect is dependent upon the speed of the
  53. ;    machine/display.
  54. ;
  55. ; PROCEDURE:
  56. ;    An integer pseudo-random number generator is used to decide
  57. ;    which tile to display.  The algorithm is taken from "Graphics Gems",
  58. ;    Andrew Glassner, ed., Academic Press, 1990, Page 221.
  59. ;
  60. ; MODIFICATION HISTORY:
  61. ;    DMS, Sept, 1990.
  62. ;-
  63.  
  64. ; Do a random dissolve, using the TV command.
  65. ; 
  66. if n_elements(siz) le 0 then siz = 32    ;Default square size....
  67. if n_elements(x0) le 0 then x0 = 0
  68. if n_elements(y0) le 0 then y0 = 0
  69. if n_elements(delay) le 0 then delay = 0.01
  70. if n_elements(order) le 0 then order = 0
  71.  
  72. s = size(image)
  73. nx = s[1]
  74. ny = s[2]
  75. siz = siz < nx < ny        ;Never smaller than dims
  76.  
  77. nxs = (nx + siz - 1) / siz    ;Squares across
  78. nys = (ny + siz - 1) / siz    ;Squares up/down
  79.  
  80.  
  81. rwidth = alog(nys)/alog(2)    ;Bits/dimension
  82. cwidth = alog(nxs)/alog(2)
  83. if rwidth ne fix(rwidth) then rwidth = rwidth + 1  ;Ceiling fcn
  84. if cwidth ne fix(cwidth) then cwidth = cwidth + 1 
  85. rwidth = fix(rwidth)
  86. cwidth = fix(cwidth)
  87. regwidth = rwidth + cwidth    ;Total width
  88.  
  89. ; The shift reg mask
  90. mask = ([ '3'xl, '6'xl, '0c'xl,'14'xl, '30'xl, '60'xl, 'b8'xl, '0110'xl, $
  91.     '240'xl, '500'xl, '0ca0'xl, '01b00'xl, '3500'xl, $
  92.     '6000'xl, 'b400'xl, '12000'xl, '20400'xl, '72000'xl, $
  93.     '90000'xl, '140000'xl, '300000'xl, '400000'xl ])[regwidth-2]
  94.  
  95. colmask = ishft(1,cwidth) -1    ;Mask to extract column
  96.  
  97. start_seq = long(systime(1) mod ishft(1,regwidth-1)) ;Random starting cell
  98. if start_seq le 0 then start_seq = 1L
  99. seq = start_seq
  100. repeat begin
  101.     row = ishft(seq, -cwidth)    ;The row chunk
  102.     col = seq and colmask        ;Col chunk
  103.     if (row lt nys) and (col  lt nxs) then begin  ;Within image?
  104.         y00 = row * siz
  105.         x00 = col * siz
  106.         y01 = (y00 + siz-1) < (ny-1)
  107.         x01 = (x00 + siz-1) < (nx-1)
  108.         if order ne 0 then $
  109.           y02 = ny - y00 - (y01-y00) > 0 else y02 = y00
  110.         tv,image[x00:x01, y00:y01], x00 + x0, y02+y0, order = order
  111.         wait,delay
  112.         endif
  113.     if seq and 1 then seq = ishft(seq, -1) xor mask $
  114.     else seq = ishft(seq, -1)
  115. endrep until seq eq start_seq
  116.  
  117. if order eq 0 then tv,image[0:siz-1, 0:siz-1],x0,y0 $    ;Last chunk
  118. else tv,image[0:siz-1, 0:siz-1],x0, y0 + ny-siz, /order
  119. empty
  120. end
  121.